Feat: initial setup for my X230 laptop

fish/.config/fish/completions/fisher.fish

@@ -0,0 +1,7 @@
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"

fish/.config/fish/config.fish

@@ -1,6 +1,5 @@
 set fish_greeting
-fish_vi_key_bindings
-set fish_bind_mode insert
+theme_gruvbox dark medium
 
 alias rm 'rm -i'
 alias nnn 'nnn -e'

fish/.config/fish/fish_plugins

@@ -0,0 +1,2 @@
+jorgebucaran/fisher
+jomik/fish-gruvbox

fish/.config/fish/fish_variables

@@ -0,0 +1,38 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR --export GTK_IM_MODULE:ibus
+SETUVAR --export QT_IM_MODULE:ibus
+SETUVAR --export SSH_AGENT_PID:946
+SETUVAR --export SSH_AUTH_SOCK:/tmp/ssh\x2dXXXXXX6HJbdl/agent\x2e945
+SETUVAR --export XMODIFIERS:\x40im\x3dibus
+SETUVAR __fish_initialized:3100
+SETUVAR _fisher_jomik_2F_fish_2D_gruvbox_files:/home/minhradz/\x2econfig/fish/functions/theme_gruvbox\x2efish
+SETUVAR _fisher_jorgebucaran_2F_fisher_files:/home/minhradz/\x2econfig/fish/functions/fisher\x2efish\x1e/home/minhradz/\x2econfig/fish/completions/fisher\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher\x1ejomik/fish\x2dgruvbox
+SETUVAR fish_color_autosuggestion:555\x1ebrblack
+SETUVAR fish_color_cancel:\x2dr
+SETUVAR fish_color_command:005fd7
+SETUVAR fish_color_comment:990000
+SETUVAR fish_color_cwd:green
+SETUVAR fish_color_cwd_root:red
+SETUVAR fish_color_end:009900
+SETUVAR fish_color_error:ff0000
+SETUVAR fish_color_escape:00a6b2
+SETUVAR fish_color_history_current:\x2d\x2dbold
+SETUVAR fish_color_host:normal
+SETUVAR fish_color_host_remote:yellow
+SETUVAR fish_color_normal:normal
+SETUVAR fish_color_operator:00a6b2
+SETUVAR fish_color_param:00afff
+SETUVAR fish_color_quote:999900
+SETUVAR fish_color_redirection:00afff
+SETUVAR fish_color_search_match:bryellow\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_status:red
+SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_valid_path:\x2d\x2dunderline
+SETUVAR fish_key_bindings:fish_default_key_bindings
+SETUVAR fish_pager_color_completion:\x1d
+SETUVAR fish_pager_color_description:B3A06D\x1eyellow
+SETUVAR fish_pager_color_prefix:normal\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
+SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan

fish/.config/fish/functions/fisher.fish

@@ -0,0 +1,211 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.3.1
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install <plugins...>  Install plugins"
+            echo "       fisher remove  <plugins...>  Remove installed plugins"
+            echo "       fisher update  <plugins...>  Update installed plugins"
+            echo "       fisher update                Update all installed plugins"
+            echo "       fisher list    [<regex>]     List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v or --version  Print version"
+            echo "       -h or --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: ~/.config/fish"
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if test ! -e $fish_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins)
+            end
+
+            for plugin in $arg_plugins
+                test -e "$plugin" && set plugin (realpath $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,functions}
+
+                fish --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set temp (command mktemp -d)
+                        set name (string split \@ $plugin) || set name[2] HEAD
+                        set url https://codeload.github.com/\$name[1]/tar.gz/\$name[2]
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        if curl --silent \$url | tar -xzC \$temp -f - 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var
+                    end
+
+                    command rm -rf $$plugin_files_var
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase _fisher_plugins[$index]
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -Rf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            set --query _fisher_plugins[1] || set --erase _fisher_plugins
+            set --query _fisher_plugins &&
+                printf "%s\n" $_fisher_plugins >$fish_plugins ||
+                command rm -f $fish_plugins
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+## Migrations ##
+function _fisher_fish_postexec --on-event fish_postexec
+    if functions --query _fisher_list
+        fisher update >/dev/null 2>/dev/null
+        set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+        test -e $XDG_DATA_HOME/fisher && command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_list _fisher_plugin_parse
+        set --erase fisher_data
+    end
+    functions --erase _fisher_fish_postexec
+end

fish/.config/fish/functions/theme_gruvbox.fish

@@ -0,0 +1,141 @@
+#!/usr/bin/fish
+function theme_gruvbox --description 'Apply gruvbox theme'
+  set -l mode 'light'
+  if test  (count $argv) -gt 0
+    set mode $argv[1]
+  end
+
+  set -g contrast 'medium'
+  if test  (count $argv) -gt 1
+    set contrast $argv[2]
+  end
+
+  switch $contrast
+  case 'soft'
+  case 'medium'
+  case 'hard'
+  case '*'
+      set_color $fish_color_error
+      echo 'Unknown contrast $contrast, choose soft, medium or hard'
+      set_color $fish_color_normal
+      return 1
+  end
+
+  switch $mode
+    case 'light'
+      __theme_gruvbox_base
+      __theme_gruvbox_light
+    case 'dark'
+      __theme_gruvbox_base
+      __theme_gruvbox_dark
+    case '*'
+      set_color $fish_color_error
+      echo 'Unknown mode $mode, choose light or dark'
+      set_color $fish_color_normal
+      return 1
+  end
+  __theme_gruvbox_palette
+  return 0
+end
+
+function __theme_gruvbox_base
+  __printf_color 1 'cc/24/1d'
+  __printf_color 2 '98/97/1a'
+  __printf_color 3 'd7/99/21'
+  __printf_color 4 '45/85/88'
+  __printf_color 5 'b1/62/86'
+  __printf_color 6 '68/9d/6a'
+end
+
+function __theme_gruvbox_light
+  set -l bg 'fb/f1/c7'
+  switch $contrast
+    case "soft"
+      set bg 'f2/e5/bc'
+    case "hard"
+      set bg 'f9/f5/d7'
+  end
+  command printf "\033]11;rgb:$bg\007"
+
+  set -l fg '3c/38/36'
+  command printf "\033]10;rgb:$fg\007"
+
+  __printf_color 0 $bg
+  __printf_color 7 '7c/6f/64'
+  __printf_color 8 '92/83/74'
+  __printf_color 9 '9d/00/06'
+  __printf_color 10 '79/74/0e'
+  __printf_color 11 'b5/76/14'
+  __printf_color 12 '07/66/78'
+  __printf_color 13 '8f/3f/71'
+  __printf_color 14 '42/7b/58'
+  __printf_color 15 $fg
+end
+
+function __theme_gruvbox_dark
+  set -l bg '28/28/28'
+  switch $contrast
+    case "soft"
+      set bg '32/30/2f'
+    case "hard"
+      set bg '1d/20/21'
+  end
+  command printf "\033]11;rgb:$bg\007"
+
+  set -l fg 'eb/db/b2'
+  command printf "\033]10;rgb:$fg\007"
+
+  __printf_color 0 $bg
+  __printf_color 7 'a8/99/84'
+  __printf_color 8 '92/83/74'
+  __printf_color 9 'fb/59/34'
+  __printf_color 10 'b8/bb/26'
+  __printf_color 11 'fa/bd/2f'
+  __printf_color 12 '83/a5/98'
+  __printf_color 13 'd3/86/9b'
+  __printf_color 14 '8e/c0/7c'
+  __printf_color 15 $fg
+end
+
+function __theme_gruvbox_palette
+  __printf_color 236 '32/30/2f'
+  __printf_color 234 '1d/20/21'
+
+  __printf_color 235 '28/28/28'
+  __printf_color 237 '3c/38/36'
+  __printf_color 239 '50/49/45'
+  __printf_color 241 '66/5c/54'
+  __printf_color 243 '7c/6f/64'
+
+  __printf_color 244 '92/83/74'
+  __printf_color 245 '92/83/74'
+
+  __printf_color 228 'f2/e5/bc'
+  __printf_color 230 'f9/f5/d7'
+
+  __printf_color 229 'fb/f1/c7'
+  __printf_color 223 'eb/db/b2'
+  __printf_color 250 'd5/c4/a1'
+  __printf_color 248 'bd/ae/93'
+  __printf_color 246 'a8/99/84'
+
+  __printf_color 167 'fb/49/34'
+  __printf_color 142 'b8/bb/26'
+  __printf_color 214 'fa/bd/2f'
+  __printf_color 109 '83/a5/98'
+  __printf_color 175 'd3/86/9b'
+  __printf_color 108 '8e/c0/7c'
+  __printf_color 208 'fe/80/19'
+
+  __printf_color 88 '9d/00/06'
+  __printf_color 100 '79/74/0e'
+  __printf_color 136 'b5/76/14'
+  __printf_color 24 '07/66/78'
+  __printf_color 96 '8f/3f/71'
+  __printf_color 66 '42/7b/58'
+  __printf_color 130 'af/3a/03'
+end
+
+function __printf_color
+  command printf "\033]4;$argv[1];rgb:$argv[2]\007"
+end